Wiki.Cyli.Org

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.

==== rem2ics ====
This script takes the simple output of remind and generates an ics compatible calendar
<code awk rem2ics>
#!/usr/bin/awk -f
# rem2ics by Anthony J. Chivetta <achivetta@gmail.com>
# version 0.1 - 2006-06-09
# version 0.2 - 2010-10-27 (one-line patch by Shane Kerr <shane@time-travellers.org>)
# version 0.3 - 2023-12-02 (indent and simplify using the -b2 argument)
# Converts output of remind -s to iCalendar
# usage: remind -s -b2 | rem2ics
#
# THE FOLLOWING CODE IS RELEASED INTO THE PUBLIC DOMAIN
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE
BEGIN {
  print "BEGIN:VCALENDAR"
  print "VERSION:2.0"
}
{
  gsub("/","",$1)
  print "BEGIN:VEVENT"
  if ($5 != "*") {
    printf("DTSTART:%dT%02d%02d00\n",$1,$5/60,$5%60)
    printf("DTEND:%dT%02d%02d00\n",$1,($5+$4)/60,($5+$4)%60)
  } else {
    printf("DTSTART:%d\n",$1)
  }
  print "SUMMARY:" substr($0,match($0,$6))
  print "END:VEVENT"
}
END {print "END:VCALENDAR"}
</code>